Dictionary

Dictionary type.

Description

Dictionary type. Associative container which contains values referenced by unique keys. Dictionaries are composed of pairs of keys (which must be unique) and values. Dictionaries will preserve the insertion order when adding elements, even though this may not be reflected when printing the dictionary. In other programming languages, this data structure is sometimes referred to as an hash map or associative array.

You can define a dictionary by placing a comma-separated list of key: value pairs in curly braces {}.

Erasing elements while iterating over them is not supported and will result in undefined behavior.

Note: Dictionaries are always passed by reference. To get a copy of a dictionary which can be modified independently of the original dictionary, use duplicate.

Creating a dictionary:

var my_dir = {} # Creates an empty dictionary.
var points_dir = {"White": 50, "Yellow": 75, "Orange": 100}
var another_dir = {
    key1: value1,
    key2: value2,
    key3: value3,
}

You can access a dictionary's values by referencing the appropriate key. In the above example, points_dir["White"] will return 50. You can also write points_dir.White, which is equivalent. However, you'll have to use the bracket syntax if the key you're accessing the dictionary with isn't a fixed string (such as a number or variable).

export(String, "White", "Yellow", "Orange") var my_color
var points_dir = {"White": 50, "Yellow": 75, "Orange": 100}

func _ready():
    # We can't use dot syntax here as `my_color` is a variable.
    var points = points_dir[my_color]

In the above code, points will be assigned the value that is paired with the appropriate color selected in my_color.

Dictionaries can contain more complex data:

my_dir = {"First Array": [1, 2, 3, 4]} # Assigns an Array to a String key.

To add a key to an existing dictionary, access it like an existing key and assign to it:

var points_dir = {"White": 50, "Yellow": 75, "Orange": 100}
points_dir["Blue"] = 150 # Add "Blue" as a key and assign 150 as its value.

Finally, dictionaries can contain different types of keys and values in the same dictionary:

# This is a valid dictionary.
# To access the string "Nested value" below, use `my_dir.sub_dir.sub_key` or `my_dir["sub_dir"]["sub_key"]`.
# Indexing styles can be mixed and matched depending on your needs.
var my_dir = {
    "String Key": 5,
    4: [1, 2, 3],
    7: "Hello",
    "sub_dir": {"sub_key": "Nested value"},
}

Note: Unlike Arrays, you can't compare dictionaries directly:

array1 = [1, 2, 3]
array2 = [1, 2, 3]

func compare_arrays():
    print(array1 == array2) # Will print true.

dir1 = {"a": 1, "b": 2, "c": 3}
dir2 = {"a": 1, "b": 2, "c": 3}

func compare_dictionaries():
    print(dir1 == dir2) # Will NOT print true.

You need to first calculate the dictionary's hash with hash before you can compare them:

dir1 = {"a": 1, "b": 2, "c": 3}
dir2 = {"a": 1, "b": 2, "c": 3}

func compare_dictionaries():
    print(dir1.hash() == dir2.hash()) # Will print true.

Tutorials

• #dictionary in GDScript basics

Methods

void	clear ( )
Dictionary	duplicate ( bool deep=false )
bool	empty ( )
bool	erase ( Variant key )
Variant	get ( Variant key, Variant default=null )
bool	has ( Variant key )
bool	has_all ( Array keys )
int	hash ( )
Array	keys ( )
int	size ( )
Array	values ( )

Method Descriptions

void clear ( )

Clear the dictionary, removing all key/value pairs.

Dictionary duplicate ( bool deep=false )

Creates a copy of the dictionary, and returns it. The deep parameter causes inner dictionaries and arrays to be copied recursively, but does not apply to objects.

bool empty ( )

Returns true if the dictionary is empty.

bool erase ( Variant key )

Erase a dictionary key/value pair by key. Returns true if the given key was present in the dictionary, false otherwise. Does not erase elements while iterating over the dictionary.

Variant get ( Variant key, Variant default=null )

Returns the current value for the specified key in the Dictionary. If the key does not exist, the method returns the value of the optional default argument, or null if it is omitted.

bool has ( Variant key )

Returns true if the dictionary has a given key.

Note: This is equivalent to using the in operator as follows:

# Will evaluate to `true`.
if "godot" in {"godot": "engine"}:
    pass

This method (like the in operator) will evaluate to true as long as the key exists, even if the associated value is null.

bool has_all ( Array keys )

Returns true if the dictionary has all of the keys in the given array.

int hash ( )

Returns a hashed integer value representing the dictionary contents. This can be used to compare dictionaries by value:

var dict1 = {0: 10}
var dict2 = {0: 10}
# The line below prints `true`, whereas it would have printed `false` if both variables were compared directly.
print(dict1.hash() == dict2.hash())

Note: Dictionaries with the same keys/values but in a different order will have a different hash.

Array keys ( )

Returns the list of keys in the Dictionary.

int size ( )

Returns the size of the dictionary (in pairs).

Array values ( )

Returns the list of values in the Dictionary.