[Java] Annotation Type Delegate

  • groovy.lang.Delegate 
@Documented
@Retention(RetentionPolicy.RUNTIME)
@Target({ElementType.FIELD, ElementType.METHOD})
@GroovyASTTransformationClass("org.codehaus.groovy.transform.DelegateASTTransformation")
public @interface Delegate

Annotation to automatically delegate part of the functionality of an owner class to the annotated delegation target. The target can be a field (or property) or a method's return value.

The delegate type is either the type of the annotated field (or property) or the return type of the annotated method. The method can be thought of as a getter or factory method for the delegate. All public instance methods present in the delegate type and not present in the owner class will be added to owner class at compile time. The implementation of such automatically added methods is code which calls through to the delegate as per the normal delegate pattern.

As an example, consider this code: 

 class Event {
     @Delegate Date when
     String title, url
 }

 def gr8conf = new Event(title: "GR8 Conference",
                           url: "http://www.gr8conf.org",
                          when: Date.parse("yyyy/MM/dd", "2009/05/18"))

 def javaOne = new Event(title: "JavaOne",
                           url: "http://java.sun.com/javaone/",
                          when: Date.parse("yyyy/MM/dd", "2009/06/02"))

 assert gr8conf.before(javaOne.when)
In this example, the Event class will have a method called before(Date otherDate) as well as other public methods of the Date class. The implementation of the before() method will look like this: 
     public boolean before(Date otherDate) {
         return when.before(otherDate);
     }
By default, the owner class will also be modified to implement any interfaces implemented by the delegate type. So, in the example above, because Date implements Cloneable the following will be true: 
 assert gr8conf instanceof Cloneable
This behavior can be disabled by setting the annotation's interfaces element to false, i.e. @Delegate(interfaces = false), e.g. in the above example, the delegate definition would become: 
     @Delegate(interfaces = false) Date when
and the following would be true: 
 assert !(gr8conf instanceof Cloneable)
If multiple delegation targets are used and the same method signature occurs in more than one of the respective delegate types, then the delegate will be made to the first defined target having that signature. If this does occur, it might be regarded as a smell (or at least poor style) and it might be clearer to do the delegation by long hand.

By default, methods of the delegate type marked as @Deprecated are not automatically added to the owner class (but see the technical note about interfaces below). You can force these methods to be added by setting the annotation's deprecated element to true, i.e. @Delegate(deprecated = true).

For example, in the example above if we change the delegate definition to: 

     @Delegate(deprecated = true) Date when
then the following additional lines will execute successfully (during 2009): 
 assert gr8conf.year + 1900 == 2009
 assert gr8conf.toGMTString().contains(" 2009 ")
Otherwise these lines produce a groovy.lang.MissingPropertyException or groovy.lang.MissingMethodException respectively as those two methods are @Deprecated in Date.

Technical notes:

  • Static methods, synthetic methods or methods from the GroovyObject interface are not candidates for delegation
  • Non-abstract non-static methods defined in the owner class or its superclasses take precedence over methods with identical signatures from a @Delegate target
  • All methods defined in the owner class (including static, abstract or private etc.) take precedence over methods with identical signatures from a @Delegate target
  • Recursive delegation to your own class is not allowed
  • Mixing of @Delegate with default method arguments is known not to work in some cases. We recommend not using these features together.
  • When the delegate type is an interface, the deprecated attribute will be ignored if the owner class implements that interface (i.e. you must set interfaces=false if you want the deprecated attribute to be used). Otherwise, the resulting class would not compile anyway without manually adding in any deprecated methods in the interface.
  • @Delegate can work in combination with @Lazy when annotating a field (or property)

Element Summary

Optional Element Summary
Type Name and Description
boolean allNames
Whether to apply the delegate pattern to all methods, including those with names that are considered internal.
boolean deprecated
Whether to apply the delegate pattern to deprecated methods; to avoid compilation errors, this is ignored if the type of the delegate target is an interface and interfaces=true.
Class[] excludeTypes
List of interfaces containing method signatures to exclude when delegating.
String[] excludes
List of method and/or property names to exclude when delegating.
Class[] includeTypes
List of interfaces containing method signatures to include when delegating.
String[] includes
List of method and/or property names to include when delegating.
boolean interfaces
Returns:
true if owner class should implement interfaces implemented by delegate type
Default:
true
boolean methodAnnotations
Whether to carry over annotations from the methods of the delegate to your delegating method.
boolean parameterAnnotations
Whether to carry over annotations from the parameters of delegate methods to your delegating method.

Inherited Methods Summary

Inherited Methods
Methods inherited from class Name
class Object wait, wait, wait, equals, toString, hashCode, getClass, notify, notifyAll

Element Detail

public boolean allNames

Whether to apply the delegate pattern to all methods, including those with names that are considered internal.

Returns:
true if owner class should delegate to methods which have internal names
Since:
2.5.0
Default:
false

public boolean deprecated

Whether to apply the delegate pattern to deprecated methods; to avoid compilation errors, this is ignored if the type of the delegate target is an interface and interfaces=true.

Deprecated:
@default false
Returns:
true if owner class should delegate to methods annotated with

public Class[] excludeTypes

List of interfaces containing method signatures to exclude when delegating. Only one of 'includes', 'includeTypes', 'excludes', 'excludeTypes' should be used. If interfaces is true (the default), you will need to manually supply any methods excluded from delegation that are required for the interface.

Since:
2.3.0
Default:
{}

public String[] excludes

List of method and/or property names to exclude when delegating. Only one of 'includes', 'includeTypes', 'excludes' or 'excludeTypes' should be used. For convenience, a String with comma separated names can be used in addition to an array (using Groovy's literal list notation) of String values. If interfaces is true (the default), you will need to manually supply any methods excluded from delegation that are required for the interface.

Since:
2.2.0
Default:
{}

public Class[] includeTypes

List of interfaces containing method signatures to include when delegating. Only one of 'includes', 'includeTypes', 'excludes' or 'excludeTypes' should be used. The default value is a special marker value indicating that no includeTypes are defined. If interfaces is true (the default), you will need to manually supply any methods excluded from delegation that are required for the interface.

Since:
2.3.0
Default:
{ Undefined.CLASS.class }

public String[] includes

List of method and/or property names to include when delegating. Only one of 'includes', 'includeTypes', 'excludes' or 'excludeTypes' should be used. For convenience, a String with comma separated names can be used in addition to an array (using Groovy's literal list notation) of String values. The default value is a special marker value indicating that no includes are defined; all fields are included if 'includes' remains undefined and 'excludes' is explicitly or implicitly an empty list. If interfaces is true (the default), you will need to manually supply any methods not included via delegation that are required for the interface.

Since:
2.2.0
Default:
{ Undefined.STRING }

public boolean interfaces

Returns:
true if owner class should implement interfaces implemented by delegate type
Default:
true

public boolean methodAnnotations

Whether to carry over annotations from the methods of the delegate to your delegating method. Currently Closure annotation members are not supported.

Returns:
true if generated delegate methods should keep method annotations
Default:
false

public boolean parameterAnnotations

Whether to carry over annotations from the parameters of delegate methods to your delegating method. Currently Closure annotation members are not supported.

Returns:
true if generated delegate methods should keep parameter annotations
Default:
false

© 2003-2020 The Apache Software Foundation
Licensed under the Apache license.
https://docs.groovy-lang.org/3.0.7/html/gapi/groovy/lang/Delegate.html