Documentation Generator

Contents

Specification
Highlighting
Macros
Using Ddoc to generate examples from unit tests
Using Ddoc for other Documentation
Security considerations
Links to D documentation generators

The D programming language enables embedding both contracts and test code along side the actual code, which helps to keep them all consistent with each other. One thing lacking is the documentation, as ordinary comments are usually unsuitable for automated extraction and formatting into manual pages. Embedding the user documentation into the source code has important advantages, such as not having to write the documentation twice, and the likelihood of the documentation staying consistent with the code.

Some existing approaches to this are:

Doxygen which already has some support for D
Java's Javadoc, probably the most well-known
C#'s embedded XML
Other documentation tools

D's goals for embedded documentation are:

It looks good as embedded documentation, not just after it is extracted and processed.
It's easy and natural to write, i.e. minimal reliance on <tags> and other clumsy forms one would never see in a finished document.
It does not repeat information that the compiler already knows from parsing the code.
It doesn't rely on embedded HTML, as such will impede extraction and formatting for other purposes.
It's based on existing D comment forms, so it is completely independent of parsers only interested in D code.
It should look and feel different from code, so it won't be visually confused with code.
It should be possible for the user to use Doxygen or other documentation extractor if desired.

Specification

The specification for the form of embedded documentation comments only specifies how information is to be presented to the compiler. It is implementation-defined how that information is used and the form of the final presentation. Whether the final presentation form is an HTML web page, a man page, a PDF file, etc. is not specified as part of the D Programming Language.

Phases of Processing

Embedded documentation comments are processed in a series of phases:

Lexical - documentation comments are identified and attached to tokens.
Parsing - documentation comments are associated with specific declarations and combined.
Sections - each documentation comment is divided up into a sequence of sections.
Special sections are processed.
Highlighting of non-special sections is done.
All sections for the module are combined.
Macro and Escape text substitution is performed to produce the final result.

Lexical

Embedded documentation comments are one of the following forms:

/** ... */ The two *'s after the opening /
/++ ... +/ The two +'s after the opening /
/// The three slashes

The following are all embedded documentation comments:

/// This is a one line documentation comment.

/** So is this. */

/++ And this. +/

/**
   This is a brief documentation comment.
 */

/**
 * The leading * on this line is not part of the documentation comment.
 */

/*********************************
   The extra *'s immediately following the /** are not
   part of the documentation comment.
 */

/++
   This is a brief documentation comment.
 +/

/++
 + The leading + on this line is not part of the documentation comment.
 +/

/+++++++++++++++++++++++++++++++++
   The extra +'s immediately following the / ++ are not
   part of the documentation comment.
 +/

/**************** Closing *'s are not part *****************/

The extra *'s and +'s on the comment opening, closing and left margin are ignored and are not part of the embedded documentation. Comments not following one of those forms are not documentation comments.

Parsing

Each documentation comment is associated with a declaration. If the documentation comment is on a line by itself or with only whitespace to the left, it refers to the next declaration. Multiple documentation comments applying to the same declaration are concatenated. Documentation comments not associated with a declaration are ignored. Documentation comments preceding the ModuleDeclaration apply to the entire module. If the documentation comment appears on the same line to the right of a declaration, it applies to that.

If a documentation comment for a declaration consists only of the identifier ditto then the documentation comment for the previous declaration at the same declaration scope is applied to this declaration as well.

If there is no documentation comment for a declaration, that declaration may not appear in the output. To ensure it does appear in the output, put an empty declaration comment for it.

int a;  /// documentation for a; b has no documentation
int b;

/** documentation for c and d */
/** more documentation for c and d */
int c;
/** ditto */
int d;

/** documentation for e and f */ int e;
int f;  /// ditto

/** documentation for g */
int g; /// more documentation for g

/// documentation for C and D
class C
{
    int x; /// documentation for C.x

    /** documentation for C.y and C.z */
    int y;
    int z; /// ditto
}

/// ditto
class D { }

Sections

The document comment is a series of Sections. A Section is a name that is the first non-blank character on a line immediately followed by a ':'. This name forms the section name. The section name is not case sensitive.

Section names starting with 'http://' or 'https://' are not recognized as section names.

Summary

The first section is the Summary, and does not have a section name. It is first paragraph, up to a blank line or a section name. While the summary can be any length, try to keep it to one line. The Summary section is optional.

Description

The next unnamed section is the Description. It consists of all the paragraphs following the Summary until a section name is encountered or the end of the comment.

While the Description section is optional, there cannot be a Description without a Summary section.

/***********************************
 * Brief summary of what
 * myfunc does, forming the summary section.
 *
 * First paragraph of synopsis description.
 *
 * Second paragraph of
 * synopsis description.
 */

void myfunc() { }

Named sections follow the Summary and Description unnamed sections.

Standard Sections

For consistency and predictability, there are several standard sections. None of these are required to be present.

Authors:: Lists the author(s) of the declaration.
Bugs:: Lists any known bugs.
Date:: Specifies the date of the current revision. The date should be in a form parseable by std.date.
Deprecated:: Provides an explanation for and corrective action to take if the associated declaration is marked as deprecated.
Examples:: Any usage examples
History:: Revision history.
License:: Any license information for copyrighted code.
Returns:: Explains the return value of the function. If the function returns void, don't redundantly document it.
See_Also:: List of other symbols and URLs to related items.
Standards:: If this declaration is compliant with any particular standard, the description of it goes here.
Throws:: Lists exceptions thrown and under what circumstances they are thrown.
Version:: Specifies the current version of the declaration.

Special Sections

Some sections have specialized meanings and syntax.

Copyright:: This contains the copyright notice. The macro COPYRIGHT is set to the contents of the section when it documents the module declaration. The copyright section only gets this special treatment when it is for the module declaration.
Params:: Function parameters can be documented by listing them in a params section. Each line that starts with an identifier followed by an '=' starts a new parameter description. A description can span multiple lines.
Macros:: The macros section follows the same syntax as the Params: section. It's a series of NAME=value pairs. The NAME is the macro name, and value is the replacement text.
Escapes=: The escapes section is a series of substitutions which replace special characters with a string. It's useful when the output format requires escaping of certain characters, for example in HTML & should be escaped with &.; The syntax is /c/string/, where c is either a single character, or multiple characters separated by whitespace or commas, and string is the replacement text.

Highlighting

Embedded Comments

The documentation comments can themselves be commented using the &dollar;(DDOC_COMMENT comment text) syntax. These comments do not nest.

Embedded Code

D code can be embedded using lines beginning with at least three hyphens -, backticks ` or tildes ~ (ignoring whitespace) to delineate the code section:

/++
 + Our function.
 +
 + Example:
 + ---
 + import std.stdio;
 +
 + void foo()
 + {
 +     writeln("foo!");  /* print the string */
 + }
 + ---
 +/

Note that in the above example the documentation comment uses the /++ ... +/ form so that /* ... */ can be used inside the code section.

D code gets automatic syntax highlighting. To include code in another language without syntax highlighting, add a language string at the end of the top delimiter line:

/++
 + Some C++
 + ``` cpp
 + #include <iostream>
 +
 + void foo()
 + {
 +     std::cout << "foo!";
 + }
 + ```
 +/

Inline Code

Inline code can be written between backtick characters (`), similarly to the syntax used on GitHub, Reddit, Stack Overflow, and other websites. Both the opening and closing ` character must appear on the same line to trigger this behavior.

Text inside these sections will be escaped according to the rules described above, then wrapped in a &dollar;(DDOC_BACKQUOTED) macro. By default, this macro expands to be displayed as an inline text span, formatted as code.

A literal backtick character can be output either as a non-paired ` on a single line or by using the &dollar;(BACKTICK) macro.

 /// Returns `true` if `a == b`.
 void foo() {}

 /// Backquoted `<html>` will be displayed to the user instead
 /// of passed through as embedded HTML (see below).
 void bar() {}

Embedded HTML

HTML can be embedded into the documentation comments, and it will be passed through to the HTML output unchanged. However, since it is not necessarily true that HTML will be the desired output format of the embedded documentation comment extractor, it is best to avoid using it where practical.

/**
 * Example of embedded HTML:
 *
 * <ol>
 *   <li><a href="http://www.digitalmars.com">Digital Mars</a></li>
 *   <li><a href="http://www.classicempire.com">Empire</a></li>
 * </ol>
 */

Headings

A long documentation section can be subdivided by adding headings. A heading is a line of text that starts with one to six # characters followed by whitespace and then the heading text. The number of # characters determines the heading level. Headings may optionally end with any number of trailing # characters.

/**
 * # H1
 * ## H2
 * ### H3
 * #### H4 ###
 * ##### H5 ##
 * ###### H6 #
 */

Links

Documentation may link to other documentation or to a URL. There are four styles of links:

/**
 * Some links:
 *
 * 1. A [reference link][ref] and bare reference links: [ref] or [Object]
 * 2. An [inline link](https://dlang.org)
 * 3. A bare URL: https://dlang.org
 * 4. An ![image](https://dlang.org/images/d3.png)
 *
 * [ref]: https://dlang.org "The D Language Website"
 */

Reference Links

Reference-style links enclose a reference label in square brackets. They may optionally be preceded by some link text, also enclosed in square brackets.

The reference label must match a reference defined elsewhere. This may be a D symbol in scope of the source code being documented, like [Object] in the example above, or it may be an explicit reference that is defined in the same documentation comment, like [ref] in the example above. In the example both instances of [ref] in item 1. will be replaced with the URL and title text from the matching definition at the bottom of the example. The first link will read reference link and the second will read ref.

Reference definitions start with a label in square brackets, followed by a colon, a URL and an optional title wrapped in single or double quotes, or in parentheses. If a reference label would match both a D symbol and a reference definition then the reference definition is used.

The generated links to D symbols are relative if they have the same root package as the module being documented. If not, their URLs are preceded by a &dollar;(DDOC_ROOT_pkg) macro, where pkg is the root package of the symbol being linked to. Links to D symbols are generated with a &dollar;(DOC_EXTENSION) macro after the module name. Then the generated URL for [Object] in the above example is as if it had been written:

&dollar;(DOC_ROOT_object)object&dollar;(DOC_EXTENSION)#.Object

DOC_ROOT_ macros can be defined for any external packages to link to using a Macros section.

Inline Links

Inline-style links enclose link text in square brackets and the link URL in parentheses. Like reference links, the URL may optionally be followed by title text wrapped in single or double quotes, or in parentheses:

/// [a link with title text](https://dlang.org 'Some title text')

Bare URLs

Bare URLs are sequences of characters that start with http:// or https://, continue with one or more characters from the set of letters, digits and -_?=%&/+#~., and contain at least one period. URL recognition happens before all macro text substitution. The URL is wrapped in a &dollar;(DDOC_LINK_AUTODETECT) macro and is otherwise left untouched.

Images

Images have the same form as reference or inline links, but add an exclamation point ! before the initial square bracket. What would be the link text in a normal link is used as the image's alt text.

Lists

Documentation may contain lists. Start an ordered list with a number followed by a period:

/**
 * 1. First this
 * 2. Then this
 *    1. A sub-item
 */

Start an unordered list with a hyphen (-), an asterisk (*) or a plus (+). Subsequent items in the same list must also start with the same symbol:

/**
 * - A list
 * - With a second item
 *
 * + A different list
 *   - With a sub-item
 *
 * * A third list (note the double asterisks)
 */

Note the double asterisks in the example above. This is because the list is inside a documentation comment that is delimited with asterisks, so the initial asterisk is considered part of the documentation comment, not a list item. This is even true when other lines don't start with an asterisk:

/**
 - A list
 * Not a list because the asterisk is part of the documentation comment
 */

/++
 + + The caveat also applies to plus-delimited documentation comments
 +/

List items can include content like new paragraphs, headings, embedded code, or child list items. Simply indent the content to match the indent of the text after the list symbol:

/**
 * - A parent list item
 *
 *   With a second paragraph
 *
 *   - A sub-item
 *     ---
 *     // A code example inside the sub-item
 *     ---
 */

Tables

Data may be placed into a table. Tables consist of a single header row, a delimiter row, and zero or more data rows. Cells in each row are separated by pipe (|) characters. Initial and trailing |'s are optional. The number of cells in the delimiter row must match the number of cells in the header row:

/**
 *  | Item | Price |
 *  | ---- | ----: |
 *  | Wigs | &dollar;10 |
 *    Wheels | &dollar;13
 *  | Widgets | &dollar;200 |
 */

Cells in the delimiter row contain hyphens (-) and optional colons (:). A : to the left of the hyphens creates a left-aligned column, a : to the right of the hyphens creates a right-aligned column (like the example above), and :'s on both sides of the hyphens create a center-aligned column.

Quotes

Documentation may include a section of quoted material by prefixing each line of the section with a >. Quotes may include headings, lists, embedded code, etc.

/**
 * > To D, or not to D. -- Willeam NerdSpeare
 */

Lines of text that directly follow a quoted line are considered part of the quote:

/**
 * > This line
 * and this line are both part of the quote
 *
 * This line is not part of the quote.
 */

Horizontal Rules

Create a horizontal rule by adding a line containing three or more asterisks, underscores or hyphens:

/**
 * ***
 * ___
 */

As with lists, note that the initial * in the example above will be stripped because it is part of a documentation comment that is delimited with asterisks. At least three subsequent asterisks are needed.

To create a horizontal rule with hyphens, add spaces between the hyphens. Without the spaces they would be treated as the start or end of an embedded code block. Note that any horizontal rule may contain spaces:

/**
 * - - -
 * _ _ _
 * * * *
 */

Text Emphasis

A span of text wrapped in asterisks (*) is emphasized, and text wrapped in two asterisks (**) is strongly emphasized:

*single asterisks* is rendered as single asterisks.

**double asterisks** is rendered as double asterisks.

Insert a literal asterisk by backslash-escaping it: \* is rendered as *.

Unlike Markdown, underscores (_) are not supported for emphasizing text because it would break snake_case names and underscore prefix processing in identifier emphasis.

Identifier Emphasis

Identifiers in documentation comments that are function parameters or are names that are in scope at the associated declaration are emphasized in the output. This emphasis can take the form of italics, boldface, a hyperlink, etc. How it is emphasized depends on what it is — a function parameter, type, D keyword, etc. To prevent unintended emphasis of an identifier, it can be preceded by an underscore (_). The underscore will be stripped from the output.

Character Entities

Some characters have special meaning to the documentation processor, to avoid confusion it can be best to replace them with their corresponding character entities:

Characters and Entities
Character	Entity
`<`	<
`>`	>
`&`	&

It is not necessary to do this inside a code section, or if the special character is not immediately followed by a # or a letter.

Punctuation Escapes

Escape any ASCII punctuation symbol with a backslash \. Doing so outputs the original character without the backslash, except for the following characters which output predefined macros instead:

Characters and Escape Macros
Character	Macro
`(`	&dollar;(LPAREN)
`)`	&dollar;(RPAREN)
`,`	&dollar;(COMMA)
`&dollar;`	&dollar;(DOLLAR)

To output a backslash, simply use two backslashes in a row: \\. Note that backslashes inside embedded or inline code do not escape punctuation and are included in the output as-is. Backslashes before non-punctation are also included in the output as-is. For example, C:\dmd2\bin\dmd.exe does not require escaping its embedded backslashes.

No Documentation

No documentation is generated for the following constructs, even if they have a documentation comment:

Invariants
Postblits
Destructors
Static constructors and static destructors
Class info, type info, and module info

Macros

The documentation comment processor includes a simple macro text preprocessor. When a &dollar;(NAME) appears in section text it is replaced with NAMEs corresponding replacement text.

For example:

/**
Macros:
 PARAM = <u>&dollar;1</u>
 MATH_DOCS = <a href="https://dlang.org/phobos/std_math.html">Math Docs</a>
*/
module math;

/**
 * This function returns the sum of &dollar;(PARAM a) and &dollar;(PARAM b).
 * See also the &dollar;(MATH_DOCS).
 */
int sum(int a, int b) { return a + b; }

The above would generate the following output:

<h1>test</h1>
<dl><dt><big><a name="sum"></a>int <u>sum</u>(int <i>a</i>, int <i>b</i>);
</big></dt>
<dd>This function returns the <u>sum</u> of <u><i>a</i></u> and <u><i>b</i></u>.
 See also the <a href="https://dlang.org/phobos/std_math.html">Math Docs</a>.
</dd>
</dl>

The replacement text is recursively scanned for more macros. If a macro is recursively encountered, with no argument or with the same argument text as the enclosing macro, it is replaced with no text. Macro invocations that cut across replacement text boundaries are not expanded. If the macro name is undefined, the replacement text has no characters in it. If a &dollar;(NAME) is desired to exist in the output without being macro expanded, the &dollar; should be backslash-escaped: \$.

Macros can have arguments. Any text from the end of the identifier to the closing ‘)’ is the &dollar;0 argument. A &dollar;0 in the replacement text is replaced with the argument text. If there are commas in the argument text, &dollar;1 will represent the argument text up to the first comma, &dollar;2 from the first comma to the second comma, etc., up to &dollar;9. &dollar;+ represents the text from the first comma to the closing ‘)’. The argument text can contain nested parentheses, "" or '' strings,  comments, or tags. If stray, unnested parentheses are used, they can be backslash-escaped: $ or $.

Macro definitions come from the following sources, in the specified order:

Predefined macros.
Definitions from file specified by sc.ini's or dmd.conf DDOCFILE setting.
Definitions from *.ddoc files specified on the command line.
Runtime definitions generated by Ddoc.
Definitions from any Macros: sections.

Macro redefinitions replace previous definitions of the same name. This means that the sequence of macro definitions from the various sources forms a hierarchy.

Macro names beginning with "D_" and "DDOC_" are reserved.

Predefined Macros

A number of macros are predefined Ddoc, and represent the minimal definitions needed by Ddoc to format and highlight the presentation. The definitions are for simple HTML.

The implementations of all predefined macros are implementation-defined. The reference implementation's macro definitions can be found here.

Ddoc does not generate HTML code. It formats into the basic formatting macros, which (in their predefined form) are then expanded into HTML. If output other than HTML is desired, then these macros need to be redefined.

Predefined Formatting Macros
Name	Description
`B`	boldface the argument
`I`	italicize the argument
`U`	underline the argument
`P`	argument is a paragraph
`DL`	argument is a definition list
`DT`	argument is a definition in a definition list
`DD`	argument is a description of a definition
`TABLE`	argument is a table
`TR`	argument is a row in a table
`TH`	argument is a header entry in a row
`TD`	argument is a data entry in a row
`OL`	argument is an ordered list
`UL`	argument is an unordered list
`LI`	argument is an item in a list
`BIG`	argument is one font size bigger
`SMALL`	argument is one font size smaller
`BR`	start new line
`LINK`	generate clickable link on argument
`LINK2`	generate clickable link, first arg is address
`RED`	argument is set to be red
`BLUE`	argument is set to be blue
`GREEN`	argument is set to be green
`YELLOW`	argument is set to be yellow
`BLACK`	argument is set to be black
`WHITE`	argument is set to be white
`D_CODE`	argument is D code
`D_INLINECODE`	argument is inline D code
`LF`	Insert a line feed (newline)
`LPAREN`	Insert a left parenthesis
`RPAREN`	Insert a right parenthesis
`BACKTICK`	Insert a backtick
`DOLLAR`	Insert a dollar sign
`DDOC`	overall template for output

DDOC is special in that it specifies the boilerplate into which the entire generated text is inserted (represented by the Ddoc generated macro BODY). For example, in order to use a style sheet, DDOC would be redefined as:

DDOC = <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN"
        "http://www.w3.org/TR/html4/strict.dtd">
    <html><head>
    <META http-equiv="content-type" content="text/html; charset=utf-8">
    <title>&dollar;(TITLE)</title>
    <link rel="stylesheet" type="text/css" href="style.css">
    </head><body>
    <h1>&dollar;(TITLE)</h1>
    &dollar;(BODY)
    </body></html>

Highlighting of D code is performed by the following macros:

D Code Formatting Macros
Name	Description
`D_COMMENT`	Highlighting of comments
`D_STRING`	Highlighting of string literals
`D_KEYWORD`	Highlighting of D keywords
`D_PSYMBOL`	Highlighting of current declaration name
`D_PARAM`	Highlighting of current function declaration parameters

The highlighting macros start with DDOC_. They control the formatting of individual parts of the presentation.

Ddoc Section Formatting Macros
Name	Description
`DDOC_CONSTRAINT`	Highlighting of a template constraint.
`DDOC_COMMENT`	Inserts a comment in the output.
`DDOC_DECL`	Highlighting of the declaration.
`DDOC_DECL_DD`	Highlighting of the description of a declaration.
`DDOC_DITTO`	Highlighting of ditto declarations.
`DDOC_SECTIONS`	Highlighting of all the sections.
`DDOC_SUMMARY`	Highlighting of the summary section.
`DDOC_DESCRIPTION`	Highlighting of the description section.
`DDOC_AUTHORS`	Highlighting of the authors section.
`DDOC_BUGS`	Highlighting of the bugs section.
`DDOC_COPYRIGHT`	Highlighting of the copyright section.
`DDOC_DATE`	Highlighting of the date section.
`DDOC_DEPRECATED`	Highlighting of the deprecated section.
`DEPRECATED`	Wrapper for deprecated declarations.
`DDOC_EXAMPLES`	Highlighting of the examples section.
`DDOC_HISTORY`	Highlighting of the history section.
`DDOC_LICENSE`	Highlighting of the license section.
`DDOC_OVERLOAD_SEPARATOR`	Inserts a separator between overloads of a given name.
`DDOC_RETURNS`	Highlighting of the returns section.
`DDOC_SEE_ALSO`	Highlighting of the see-also section.
`DDOC_STANDARDS`	Highlighting of the standards section.
`DDOC_THROWS`	Highlighting of the throws section.
`DDOC_VERSION`	Highlighting of the version section.
`DDOC_SECTION_H`	Highlighting of the section name of a non-standard section.
`DDOC_SECTION`	Highlighting of the contents of a non-standard section.
`DDOC_MEMBERS`	Default highlighting of all the members of a class, struct, etc.
`DDOC_MODULE_MEMBERS`	Highlighting of all the members of a module.
`DDOC_CLASS_MEMBERS`	Highlighting of all the members of a class.
`DDOC_STRUCT_MEMBERS`	Highlighting of all the members of a struct.
`DDOC_ENUM_MEMBERS`	Highlighting of all the members of an enum.
`DDOC_TEMPLATE_PARAM`	Highlighting of a template's individual parameters.
`DDOC_TEMPLATE_PARAM_LIST`	Highlighting of a template's parameter list.
`DDOC_TEMPLATE_MEMBERS`	Highlighting of all the members of a template.
`DDOC_ENUM_BASETYPE`	Highlighting of the type an enum is based upon
`DDOC_PARAMS`	Highlighting of a function parameter section.
`DDOC_PARAM_ROW`	Highlighting of a name=value function parameter.
`DDOC_PARAM_ID`	Highlighting of the parameter name.
`DDOC_PARAM_DESC`	Highlighting of the parameter value.
`DDOC_BLANKLINE`	Inserts a blank line.
`DDOC_ANCHOR`	Expands to a named anchor used for hyperlinking to a particular declaration section. Argument &dollar;1 expands to the qualified declaration name.
`DDOC_PSYMBOL`	Highlighting of declaration name to which a particular section is referring.
`DDOC_PSUPER_SYMBOL`	Highlighting of the base type of a class.
`DDOC_KEYWORD`	Highlighting of D keywords.
`DDOC_PARAM`	Highlighting of function parameters.
`DDOC_BACKQUOTED`	Inserts inline code.
`DDOC_AUTO_PSYMBOL_SUPPRESS`	Highlighting of auto-detected symbol that starts with underscore
`DDOC_AUTO_PSYMBOL`	Highlighting of auto-detected symbol
`DDOC_AUTO_KEYWORD`	Highlighting of auto-detected keywords
`DDOC_AUTO_PARAM`	Highlighting of auto-detected parameters

For example, one could redefine DDOC_SUMMARY:

DDOC_SUMMARY = &dollar;(GREEN &dollar;0)

And all the summary sections will now be green.

Macro Definitions from `sc.ini`'s DDOCFILE

A text file of macro definitions can be created, and specified in sc.ini:

DDOCFILE=myproject.ddoc

Macro Definitions from .ddoc Files on the Command Line

File names on the DMD command line with the extension .ddoc are text files that are read and processed in order.

Macro Definitions Generated by Ddoc

Generated Macro Definitions
Macro Name	Content
BODY	Set to the generated document text.
TITLE	Set to the module name.
DATETIME	Set to the current date and time.
YEAR	Set to the current year.
COPYRIGHT	Set to the contents of any Copyright: section that is part of the module comment.
DOCFILENAME	Set to the name of the generated output file.
SRCFILENAME	Set to the name of the source file the documentation is being generated from.

Using Ddoc to generate examples from unit tests

Ddoc can automatically generate usage examples for declarations using unit tests. If a declaration is followed by a documented unit test, the code from the test will be inserted into the example section of the declaration. This avoids the frequent problem of having outdated documentation for pieces of code.

To create a documented unit test just add three forward slashes before the unittest block, like this:

///
unittest
{
    ...
}

For more information please see the full section on documented unit tests.

Using Ddoc for other Documentation

Ddoc is primarily designed for use in producing documentation from embedded comments. It can also, however, be used for processing other general documentation. The reason for doing this would be to take advantage of the macro capability of Ddoc and the D code syntax highlighting capability.

If the .d source file starts with the string "Ddoc" then it is treated as general purpose documentation, not as a D code source file. From immediately after the "Ddoc" string to the end of the file or any "Macros:" section forms the document. No automatic highlighting is done to that text, other than highlighting of D code embedded between lines delineated with --- lines. Only macro processing is done.

Much of the D documentation itself is generated this way, including this page. Such documentation is marked at the bottom as being generated by Ddoc.

Security considerations

Note that DDoc comments may embed raw HTML, including <script> tags. Be careful when publishing or distributing rendered DDoc HTML generated from untrusted sources, as this may allow cross-site scripting.

Links to D documentation generators

A list of current D documentation generators which use Ddoc can be found on our wiki page.