clojure.test

by Stuart Sierra, with contributions and suggestions by Chas Emerick, Allen Rohner, and Stuart Halloway

Full namespace name: clojure.test

Overview

A unit testing framework.

ASSERTIONS

The core of the library is the "is" macro, which lets you make
assertions of any arbitrary expression:

(is (= 4 (+ 2 2)))
(is (instance? Integer 256))
(is (.startsWith "abcde" "ab"))

You can type an "is" expression directly at the REPL, which will
print a message if it fails.

    user> (is (= 5 (+ 2 2)))

    FAIL in  (:1)
    expected: (= 5 (+ 2 2))
      actual: (not (= 5 4))
    false

The "expected:" line shows you the original expression, and the
"actual:" shows you what actually happened.  In this case, it
shows that (+ 2 2) returned 4, which is not = to 5.  Finally, the
"false" on the last line is the value returned from the
expression.  The "is" macro always returns the result of the
inner expression.

There are two special assertions for testing exceptions.  The
"(is (thrown? c ...))" form tests if an exception of class c is
thrown:

(is (thrown? ArithmeticException (/ 1 0))) 

"(is (thrown-with-msg? c re ...))" does the same thing and also
tests that the message on the exception matches the regular
expression re:

(is (thrown-with-msg? ArithmeticException #"Divide by zero"
                      (/ 1 0)))

DOCUMENTING TESTS

"is" takes an optional second argument, a string describing the
assertion.  This message will be included in the error report.

(is (= 5 (+ 2 2)) "Crazy arithmetic")

In addition, you can document groups of assertions with the
"testing" macro, which takes a string followed by any number of
assertions.  The string will be included in failure reports.
Calls to "testing" may be nested, and all of the strings will be
joined together with spaces in the final report, in a style
similar to RSpec <http://rspec.info/>

(testing "Arithmetic"
  (testing "with positive integers"
    (is (= 4 (+ 2 2)))
    (is (= 7 (+ 3 4))))
  (testing "with negative integers"
    (is (= -4 (+ -2 -2)))
    (is (= -1 (+ 3 -4)))))

Note that, unlike RSpec, the "testing" macro may only be used
INSIDE a "deftest" or "with-test" form (see below).


DEFINING TESTS

There are two ways to define tests.  The "with-test" macro takes
a defn or def form as its first argument, followed by any number
of assertions.  The tests will be stored as metadata on the
definition.

(with-test
    (defn my-function [x y]
      (+ x y))
  (is (= 4 (my-function 2 2)))
  (is (= 7 (my-function 3 4))))

As of Clojure SVN rev. 1221, this does not work with defmacro.
See http://code.google.com/p/clojure/issues/detail?id=51

The other way lets you define tests separately from the rest of
your code, even in a different namespace:

(deftest addition
  (is (= 4 (+ 2 2)))
  (is (= 7 (+ 3 4))))

(deftest subtraction
  (is (= 1 (- 4 3)))
  (is (= 3 (- 7 4))))

This creates functions named "addition" and "subtraction", which
can be called like any other function.  Therefore, tests can be
grouped and composed, in a style similar to the test framework in
Peter Seibel's "Practical Common Lisp"
<http://www.gigamonkeys.com/book/practical-building-a-unit-test-framework.html>

(deftest arithmetic
  (addition)
  (subtraction))

The names of the nested tests will be joined in a list, like
"(arithmetic addition)", in failure reports.  You can use nested
tests to set up a context shared by several tests.


RUNNING TESTS

Run tests with the function "(run-tests namespaces...)":

(run-tests 'your.namespace 'some.other.namespace)

If you don't specify any namespaces, the current namespace is
used.  To run all tests in all namespaces, use "(run-all-tests)".

By default, these functions will search for all tests defined in
a namespace and run them in an undefined order.  However, if you
are composing tests, as in the "arithmetic" example above, you
probably do not want the "addition" and "subtraction" tests run
separately.  In that case, you must define a special function
named "test-ns-hook" that runs your tests in the correct order:

(defn test-ns-hook []
  (arithmetic))

Note: test-ns-hook prevents execution of fixtures (see below).


OMITTING TESTS FROM PRODUCTION CODE

You can bind the variable "*load-tests*" to false when loading or
compiling code in production.  This will prevent any tests from
being created by "with-test" or "deftest".


FIXTURES

Fixtures allow you to run code before and after tests, to set up
the context in which tests should be run.

A fixture is just a function that calls another function passed as
an argument.  It looks like this:

(defn my-fixture [f]
   Perform setup, establish bindings, whatever.
  (f)  Then call the function we were passed.
   Tear-down / clean-up code here.
 )

Fixtures are attached to namespaces in one of two ways.  "each"
fixtures are run repeatedly, once for each test function created
with "deftest" or "with-test".  "each" fixtures are useful for
establishing a consistent before/after state for each test, like
clearing out database tables.

"each" fixtures can be attached to the current namespace like this:
(use-fixtures :each fixture1 fixture2 ...)
The fixture1, fixture2 are just functions like the example above.
They can also be anonymous functions, like this:
(use-fixtures :each (fn [f] setup... (f) cleanup...))

The other kind of fixture, a "once" fixture, is only run once,
around ALL the tests in the namespace.  "once" fixtures are useful
for tasks that only need to be performed once, like establishing
database connections, or for time-consuming tasks.

Attach "once" fixtures to the current namespace like this:
(use-fixtures :once fixture1 fixture2 ...)

Note: Fixtures and test-ns-hook are mutually incompatible.  If you
are using test-ns-hook, fixture functions will *never* be run.


SAVING TEST OUTPUT TO A FILE

All the test reporting functions write to the var *test-out*.  By
default, this is the same as *out*, but you can rebind it to any
PrintWriter.  For example, it could be a file opened with
clojure.java.io/writer.


EXTENDING TEST-IS (ADVANCED)

You can extend the behavior of the "is" macro by defining new
methods for the "assert-expr" multimethod.  These methods are
called during expansion of the "is" macro, so they should return
quoted forms to be evaluated.

You can plug in your own test-reporting framework by rebinding
the "report" function: (report event)

The 'event' argument is a map.  It will always have a :type key,
whose value will be a keyword signaling the type of event being
reported.  Standard events with :type value of :pass, :fail, and
:error are called when an assertion passes, fails, and throws an
exception, respectively.  In that case, the event will also have
the following keys:

  :expected   The form that was expected to be true
  :actual     A form representing what actually occurred
  :message    The string message given as an argument to 'is'

The "testing" strings will be a list in "*testing-contexts*", and
the vars being tested will be a list in "*testing-vars*".

Your "report" function should wrap any printing calls in the
"with-test-out" macro, which rebinds *out* to the current value
of *test-out*.

For additional event types, see the examples in the code.

Public Variables and Functions

*load-tests*dynamic var

True by default.  If set to false, no test functions will
be created by deftest, set-test, or with-test.  Use this to omit
tests when compiling or loading production code.

Added in Clojure version 1.1

Source

*stack-trace-depth*dynamic var

The maximum depth of stack traces to print when an Exception
is thrown during a test.  Defaults to nil, which means print the 
complete stack trace.

Added in Clojure version 1.1

Source

aremacro

Usage: (are argv expr & args)

Checks multiple assertions with a template expression.
See clojure.template/do-template for an explanation of
templates.

Example: (are [x y] (= x y)  
              2 (+ 1 1)
              4 (* 2 2))
Expands to: 
         (do (is (= 2 (+ 1 1)))
             (is (= 4 (* 2 2))))

Note: This breaks some reporting features, such as line numbers.

Added in Clojure version 1.1

Source

assert-anyfunction

Usage: (assert-any msg form)

Returns generic assertion code for any test, including macros, Java
method calls, or isolated symbols.

Added in Clojure version 1.1

Source

assert-predicatefunction

Usage: (assert-predicate msg form)

Returns generic assertion code for any functional predicate.  The
'expected' argument to 'report' will contains the original form, the
'actual' argument will contain the form with all its sub-forms
evaluated.  If the predicate returns false, the 'actual' form will
be wrapped in (not...).

Added in Clojure version 1.1

Source

compose-fixturesfunction

Usage: (compose-fixtures f1 f2)

Composes two fixture functions, creating a new fixture function
that combines their behavior.

Added in Clojure version 1.1

Source

deftestmacro

Usage: (deftest name & body)

Defines a test function with no arguments.  Test functions may call
other tests, so tests may be composed.  If you compose tests, you
should also define a function named test-ns-hook; run-tests will
call test-ns-hook instead of testing all vars.

Note: Actually, the test body goes in the :test metadata on the var,
and the real function (the value of the var) calls test-var on
itself.

When *load-tests* is false, deftest is ignored.

Added in Clojure version 1.1

Source

deftest-macro

Usage: (deftest- name & body)

Like deftest but creates a private var.

Added in Clojure version 1.1

Source

do-reportfunction

Usage: (do-report m)

Add file and line information to a test result and call report.
If you are writing a custom assert-expr method, call this function
to pass test results to report.

Added in Clojure version 1.2

Source

file-positionfunction

Usage: (file-position n)

Returns a vector [filename line-number] for the nth call up the
stack.

Deprecated in 1.2: The information needed for test reporting is
now on :file and :line keys in the result map.

Added in Clojure version 1.1

Deprecated since Clojure version 1.2

Source

function?function

Usage: (function? x)

Returns true if argument is a function or a symbol that resolves to
a function (not a macro).

Added in Clojure version 1.1

Source

get-possibly-unbound-varfunction

Usage: (get-possibly-unbound-var v)

Like var-get but returns nil if the var is unbound.

Added in Clojure version 1.1

Source

inc-report-counterfunction

Usage: (inc-report-counter name)

Increments the named counter in *report-counters*, a ref to a map.
Does nothing if *report-counters* is nil.

Added in Clojure version 1.1

Source

ismacro

Usage: (is form)
       (is form msg)

Generic assertion macro.  'form' is any predicate test.
'msg' is an optional message to attach to the assertion.

Example: (is (= 4 (+ 2 2)) "Two plus two should be 4")

Special forms:

(is (thrown? c body)) checks that an instance of c is thrown from
body, fails if not; then returns the thing thrown.

(is (thrown-with-msg? c re body)) checks that an instance of c is
thrown AND that the message on the exception matches (with
re-find) the regular expression re.

Added in Clojure version 1.1

Source

join-fixturesfunction

Usage: (join-fixtures fixtures)

Composes a collection of fixtures, in order.  Always returns a valid
fixture function, even if the collection is empty.

Added in Clojure version 1.1

Source

reportdynamic multimethod

No usage documentation available

Generic reporting function, may be overridden to plug in
different report formats (e.g., TAP, JUnit).  Assertions such as
'is' call 'report' to indicate results.  The argument given to
'report' will be a map with a :type key.  See the documentation at
the top of test_is.clj for more information on the types of
arguments for 'report'.

Added in Clojure version 1.1

Source

run-all-testsfunction

Usage: (run-all-tests)
       (run-all-tests re)

Runs all tests in all namespaces; prints results.
Optional argument is a regular expression; only namespaces with
names matching the regular expression (with re-matches) will be
tested.

Added in Clojure version 1.1

Source

run-testsfunction

Usage: (run-tests)
       (run-tests & namespaces)

Runs all tests in the given namespaces; prints results.
Defaults to current namespace if none given.  Returns a map
summarizing test results.

Added in Clojure version 1.1

Source

set-testmacro

Usage: (set-test name & body)

Experimental.
Sets :test metadata of the named var to a fn with the given body.
The var must already exist.  Does not modify the value of the var.

When *load-tests* is false, set-test is ignored.

Added in Clojure version 1.1

Source

successful?function

Usage: (successful? summary)

Returns true if the given test summary indicates all tests
were successful, false otherwise.

Added in Clojure version 1.1

Source

test-all-varsfunction

Usage: (test-all-vars ns)

Calls test-vars on every var interned in the namespace, with fixtures.

Added in Clojure version 1.1

Source

test-nsfunction

Usage: (test-ns ns)

If the namespace defines a function named test-ns-hook, calls that.
Otherwise, calls test-all-vars on the namespace.  'ns' is a
namespace object or a symbol.

Internally binds *report-counters* to a ref initialized to
*initial-report-counters*.  Returns the final, dereferenced state of
*report-counters*.

Added in Clojure version 1.1

Source

test-vardynamic function

Usage: (test-var v)

If v has a function in its :test metadata, calls that function,
with *testing-vars* bound to (conj *testing-vars* v).

Added in Clojure version 1.1

Source

test-varsfunction

Usage: (test-vars vars)

Groups vars by their namespace and runs test-vars on them with
appropriate fixtures applied.

Added in Clojure version 1.6

Source

testingmacro

Usage: (testing string & body)

Adds a new string to the list of testing contexts.  May be nested,
but must occur inside a test function (deftest).

Added in Clojure version 1.1

Source

testing-contexts-strfunction

Usage: (testing-contexts-str)

Returns a string representation of the current test context. Joins
strings in *testing-contexts* with spaces.

Added in Clojure version 1.1

Source

testing-vars-strfunction

Usage: (testing-vars-str m)

Returns a string representation of the current test.  Renders names
in *testing-vars* as a list, then the source file and line of
current assertion.

Added in Clojure version 1.1

Source

try-exprmacro

Usage: (try-expr msg form)

Used by the 'is' macro to catch unexpected exceptions.
You don't call this.

Added in Clojure version 1.1

Source

use-fixturesmultimethod

No usage documentation available

Wrap test runs in a fixture function to perform setup and
teardown. Using a fixture-type of :each wraps every test
individually, while :once wraps the whole run in a single function.

Added in Clojure version 1.1

Source

with-testmacro

Usage: (with-test definition & body)

Takes any definition form (that returns a Var) as the first argument.
Remaining body goes in the :test metadata function for that Var.

When *load-tests* is false, only evaluates the definition, ignoring
the tests.

Added in Clojure version 1.1

Source

with-test-outmacro

Usage: (with-test-out & body)

Runs body with *out* bound to the value of *test-out*.

Added in Clojure version 1.1

Source

clojure.test.junit

clojure.test extension for JUnit-compatible XML output.

JUnit (http://junit.org/) is the most popular unit-testing library
for Java.  As such, tool support for JUnit output formats is
common.  By producing compatible output from tests, this tool
support can be exploited.

To use, wrap any calls to clojure.test/run-tests in the
with-junit-output macro, like this:

  (use 'clojure.test)
  (use 'clojure.test.junit)

  (with-junit-output
    (run-tests 'my.cool.library))

To write the output to a file, rebind clojure.test/*test-out* to
your own PrintWriter (perhaps opened using
clojure.java.io/writer).

Public Variables and Functions

with-junit-outputmacro

Usage: (with-junit-output & body)

Execute body with modified test-is reporting functions that write
JUnit-compatible XML output.

Added in Clojure version 1.1

Source

clojure.test.tap

clojure.test extensions for the Test Anything Protocol (TAP)

TAP is a simple text-based syntax for reporting test results.  TAP
was originally developed for Perl, and now has implementations in
several languages.  For more information on TAP, see
http://testanything.org/ and
http://search.cpan.org/~petdance/TAP-1.0.0/TAP.pm

To use this library, wrap any calls to
clojure.test/run-tests in the with-tap-output macro,
like this:

  (use 'clojure.test)
  (use 'clojure.test.tap)

  (with-tap-output
   (run-tests 'my.cool.library))

Public Variables and Functions

print-tap-diagnosticfunction

Usage: (print-tap-diagnostic data)

Prints a TAP diagnostic line.  data is a (possibly multi-line)
string.

Added in Clojure version 1.1

Source

print-tap-failfunction

Usage: (print-tap-fail msg)

Prints a TAP 'not ok' line.  msg is a string, with no line breaks

Added in Clojure version 1.1

Source

print-tap-passfunction

Usage: (print-tap-pass msg)

Prints a TAP 'ok' line.  msg is a string, with no line breaks

Added in Clojure version 1.1

Source

print-tap-planfunction

Usage: (print-tap-plan n)

Prints a TAP plan line like '1..n'.  n is the number of tests

Added in Clojure version 1.1

Source

with-tap-outputmacro

Usage: (with-tap-output & body)

Execute body with modified test reporting functions that produce
TAP output

Added in Clojure version 1.1

Source